TeraTerm自動ログ取得マクロ－ログ整理版(ホスト別) ｜ Tera Term(テラターム)の便利な使い方

Tera Termマクロ等で自動ログ取得設定を行っていると、いつの間にかログが溜まってしまい、いざ必要な時に対象のログファイルが見つからない事が多々あります。

そこでここでは、自動で取得するログを整理（保存先を操作）する方法をご紹介したいと思います。前回の『Tera Term自動ログ取得マクロ－ログ整理版（年月別）』の応用版になります。

指定のフォルダ配下に、接続時に入力する「ホスト名 or IPアドレス」のフォルダを自動で作成し、取得したログを、ホスト別に整理して保存していきます。下記例では、IPアドレスで接続し、IPアドレスのフォルダが作成されています。
ホスト別にログを保管整理

マクロ側でログ取得を制御しますので、「設定」メニューから「その他の設定」を選択し、「ログ」タブより「自動的にログ採取を開始する」のチェックは外しておいてください。

その他の機能の特徴としては、以下のようになっています。

接続するホスト情報はメニューから入力
接続ユーザは固定で設定
パスワードは初回ログイン時は入力が必要。次回からはパスワード入力無しでログイン。（パスワードはファイルに暗号化して保存）
ログは指定のフォルダ配下に、ホスト名（IPアドレス）のフォルダを作成し整理して保存

SSH自動ログ取得マクロ

;=====================================================
; Filename    : Log-arrangement_02.ttl
; Description : Auto login & Log save with teraterm
; Author      : JUNZOU
; Created     : 2011/10/16
; modified    : 
;=====================================================
;; ログ保存場所指定
LOG_PATH = 'C:\teraterm\'
;; ユーザ名指定
USERNAME = 'ユーザ名'
;; パスワードファイル指定
PASSFILE = 'C:\password.dat'
;=====================================================
;; ①接続先ホスト名 or IPアドレス入力
inputbox '[Hostname] or [IP Address]' 'Please input the hostname or an IP address.'
HOSTNAME = inputstr

;; ②入力確認(ホスト名 or IPアドレスの入力が無い場合は終了)
strcompare HOSTNAME ''
if result = 0 then
    messagebox 'The hostname or IP address is not input.' 'Input error'
    end
endif

;; ③パスワード取得 
getpassword PASSFILE USERNAME PASSWORD

;; ④ログファイル保存フォルダの設定
LOG_FILE = LOG_PATH
strconcat LOG_FILE HOSTNAME

;; ⑤ログ保存フォルダの存在確認（無ければ作成：作成失敗は終了）
foldersearch LOG_FILE
if result = 0 then
    foldercreate LOG_FILE
    if result <> 0 then
        messagebox 'A folder could not be made.' 'Making error'
        end
    endif    
endif

;; ⑥ログファイル名の設定
getdate LOG_NAME '\%Y%m%d_%H%M%S_&h.log'
strconcat LOG_FILE LOG_NAME

;; ⑦SSH接続コマンド作成
COMMAND = HOSTNAME
strconcat COMMAND ':22 /ssh /2 /auth=password /user='
strconcat COMMAND USERNAME
strconcat COMMAND ' /passwd='
strconcat COMMAND PASSWORD

;; ⑧SSH接続
connect COMMAND

;; ⑨接続出来ない場合はメッセージを表示し終了
if result <> 2 then
    messagebox 'It could not be connected.' 'Connected error'
    end
endif

;; ⑩10秒以内にプロンプトが表示されない場合終了
timeout = 10
wait '$' '#'
if result = 0 then
    disconnect
    end
endif

;;⑪ログ取得開始
logopen LOG_FILE 1 1
sendln 'hostname'
wait '$' '#'

;; ⑫マクロ終了
end